@echo off

echo Auto FTP Backup Running.....

rem バックアップファイル名の設定
set BACKUP_FILE=man_cp.txt

rem 環境変数の既存の値に文字列を追加
set BACKUP_FILE=%BACKUP_FILE% tmp_index.htm
set BACKUP_FILE=%BACKUP_FILE% box01-5.LZH

rem ログファイル名の設定
set LOG_FILE=ftp_log.txt

rem 日時の書き出し
echo %date% %time%   >> %LOG_FILE%

rem 空行の書き出し
echo.                >> %LOG_FILE%

rem コマンドファイルを指定して実行
ftp -i -s:ftp_login.txt  >> %LOG_FILE%

echo.                >> %LOG_FILE%

rem バックアップファイルに曜日を付加した名前に変更
rem これによって、１週間分を確保しておける

rem 曜日取得のために変数
set EXT_STRING=

rem ファイル名に追加する文字列を取得
for /f "usebackq tokens=1-4 delims=/ " %%i in (
  `date /t`
) do (
  rem i なら年 j なら月 k なら日 l なら曜日
  set EXT_STRING=%%l
)

rem ダウンロードしたファイル名を変更する
for %%i in (%BACKUP_FILE%) do (
  rem 変更する名前のファイルが既に存在したら削除
  if exist %%~ni_%EXT_STRING%.%%~xi (
    echo Delete %%~ni_%EXT_STRING%.%%~xi >> %LOG_FILE%
    del %%~ni_%EXT_STRING%.%%~xi
  )
  rem 名前の変更
  echo Rename man_cp.txt -^> %%~ni_%EXT_STRING%.%%~xi >> %LOG_FILE%
  ren %%i %%~ni_%EXT_STRING%.%%~xi
)

echo.                >> %LOG_FILE%
echo.                >> %LOG_FILE%

exit 0